@echo off
chcp 936 >nul
title 分子世界 · 案例运行器 · 串行
cd /d "%~dp0"

echo.
echo ============================================================
echo   分子世界 · 探微寻幽   LAMMPS 算例运行器（串行）
echo ============================================================
echo.
echo   工作目录：%CD%
echo.

set "INP="
for %%f in (in.*) do if not defined INP set "INP=%%f"
if not defined INP goto :noinput
if not exist "%INP%" goto :noinput

echo   输入脚本：%INP%
echo.

where lmp >nul 2>nul
if errorlevel 1 goto :nolmp

echo   正在运行，请稍候……
echo   ------------------------------------------------------------
lmp -in "%INP%"
echo   ------------------------------------------------------------
echo.
echo   运行结束。本目录下应当多出这些文件：
if exist log.lammps echo      log.lammps   完整日志，含每一步的热力学量
if exist dump.lj    echo      dump.lj      轨迹文件，可用 OVITO 打开
if exist dump.cu    echo      dump.cu      轨迹文件，可用 OVITO 打开
echo.
echo   屏幕上若有报错，请打开 log.lammps 查看完整信息。
echo.
pause
exit /b 0

:noinput
echo   [--] 本目录下没有找到 in.* 输入脚本。
echo        请把 in.lj 或 in.cu 与本脚本放在同一个文件夹里。
echo.
pause
exit /b 1

:nolmp
echo   [--] 没有找到 lmp 命令。
echo.
echo   可以这样处理：
echo     1. 若尚未安装 LAMMPS，先看第 1 章 1.4 节；
echo     2. 最稳妥的做法是打开「开始」菜单里的 LAMMPS Shell，
echo        在本目录下手动执行：  lmp -in %INP%
echo.
pause
exit /b 1